88 lines
2.1 KiB
ArmAsm
88 lines
2.1 KiB
ArmAsm
![]() |
/*
|
||
|
* Copyright 2012 Tilera Corporation. All Rights Reserved.
|
||
|
*
|
||
|
* This program is free software; you can redistribute it and/or
|
||
|
* modify it under the terms of the GNU General Public License
|
||
|
* as published by the Free Software Foundation, version 2.
|
||
|
*
|
||
|
* This program is distributed in the hope that it will be useful, but
|
||
|
* WITHOUT ANY WARRANTY; without even the implied warranty of
|
||
|
* MERCHANTABILITY OR FITNESS FOR A PARTICULAR PURPOSE, GOOD TITLE or
|
||
|
* NON INFRINGEMENT. See the GNU General Public License for
|
||
|
* more details.
|
||
|
*/
|
||
|
|
||
|
#define VDSO_VERSION_STRING LINUX_2.6
|
||
|
|
||
|
|
||
|
OUTPUT_ARCH(tile)
|
||
|
|
||
|
/* The ELF entry point can be used to set the AT_SYSINFO value. */
|
||
|
ENTRY(__vdso_rt_sigreturn);
|
||
|
|
||
|
|
||
|
SECTIONS
|
||
|
{
|
||
|
. = SIZEOF_HEADERS;
|
||
|
|
||
|
.hash : { *(.hash) } :text
|
||
|
.gnu.hash : { *(.gnu.hash) }
|
||
|
.dynsym : { *(.dynsym) }
|
||
|
.dynstr : { *(.dynstr) }
|
||
|
.gnu.version : { *(.gnu.version) }
|
||
|
.gnu.version_d : { *(.gnu.version_d) }
|
||
|
.gnu.version_r : { *(.gnu.version_r) }
|
||
|
|
||
|
.note : { *(.note.*) } :text :note
|
||
|
.dynamic : { *(.dynamic) } :text :dynamic
|
||
|
|
||
|
.eh_frame_hdr : { *(.eh_frame_hdr) } :text :eh_frame_hdr
|
||
|
.eh_frame : { KEEP (*(.eh_frame)) } :text
|
||
|
|
||
|
.rodata : { *(.rodata .rodata.* .gnu.linkonce.r.*) }
|
||
|
|
||
|
/*
|
||
|
* This linker script is used both with -r and with -shared.
|
||
|
* For the layouts to match, we need to skip more than enough
|
||
|
* space for the dynamic symbol table et al. If this amount
|
||
|
* is insufficient, ld -shared will barf. Just increase it here.
|
||
|
*/
|
||
|
. = 0x1000;
|
||
|
.text : { *(.text .text.*) } :text
|
||
|
|
||
|
.data : {
|
||
|
*(.got.plt) *(.got)
|
||
|
*(.data .data.* .gnu.linkonce.d.*)
|
||
|
*(.dynbss)
|
||
|
*(.bss .bss.* .gnu.linkonce.b.*)
|
||
|
}
|
||
|
}
|
||
|
|
||
|
|
||
|
/*
|
||
|
* We must supply the ELF program headers explicitly to get just one
|
||
|
* PT_LOAD segment, and set the flags explicitly to make segments read-only.
|
||
|
*/
|
||
|
PHDRS
|
||
|
{
|
||
|
text PT_LOAD FLAGS(5) FILEHDR PHDRS; /* PF_R|PF_X */
|
||
|
dynamic PT_DYNAMIC FLAGS(4); /* PF_R */
|
||
|
note PT_NOTE FLAGS(4); /* PF_R */
|
||
|
eh_frame_hdr PT_GNU_EH_FRAME;
|
||
|
}
|
||
|
|
||
|
|
||
|
/*
|
||
|
* This controls what userland symbols we export from the vDSO.
|
||
|
*/
|
||
|
VERSION
|
||
|
{
|
||
|
VDSO_VERSION_STRING {
|
||
|
global:
|
||
|
__vdso_rt_sigreturn;
|
||
|
__vdso_gettimeofday;
|
||
|
gettimeofday;
|
||
|
local:*;
|
||
|
};
|
||
|
}
|