6727ad9e20
When doing an nmi backtrace of many cores, most of which are idle, the output is a little overwhelming and very uninformative. Suppress messages for cpus that are idling when they are interrupted and just emit one line, "NMI backtrace for N skipped: idling at pc 0xNNN". We do this by grouping all the cpuidle code together into a new .cpuidle.text section, and then checking the address of the interrupted PC to see if it lies within that section. This commit suitably tags x86 and tile idle routines, and only adds in the minimal framework for other architectures. Link: http://lkml.kernel.org/r/1472487169-14923-5-git-send-email-cmetcalf@mellanox.com Signed-off-by: Chris Metcalf <cmetcalf@mellanox.com> Acked-by: Peter Zijlstra (Intel) <peterz@infradead.org> Tested-by: Peter Zijlstra (Intel) <peterz@infradead.org> Tested-by: Daniel Thompson <daniel.thompson@linaro.org> [arm] Tested-by: Petr Mladek <pmladek@suse.com> Cc: Aaron Tomlin <atomlin@redhat.com> Cc: Peter Zijlstra (Intel) <peterz@infradead.org> Cc: "Rafael J. Wysocki" <rjw@rjwysocki.net> Cc: Russell King <linux@arm.linux.org.uk> Cc: Thomas Gleixner <tglx@linutronix.de> Cc: Ingo Molnar <mingo@elte.hu> Signed-off-by: Andrew Morton <akpm@linux-foundation.org> Signed-off-by: Linus Torvalds <torvalds@linux-foundation.org>
105 lines
2.2 KiB
ArmAsm
105 lines
2.2 KiB
ArmAsm
#include <asm-generic/vmlinux.lds.h>
|
|
#include <asm/page.h>
|
|
#include <asm/cache.h>
|
|
#include <asm/thread_info.h>
|
|
#include <hv/hypervisor.h>
|
|
|
|
/* Text loads starting from the supervisor interrupt vector address. */
|
|
#define TEXT_OFFSET MEM_SV_START
|
|
|
|
OUTPUT_ARCH(tile)
|
|
ENTRY(_start)
|
|
jiffies = jiffies_64;
|
|
|
|
PHDRS
|
|
{
|
|
intrpt PT_LOAD ;
|
|
text PT_LOAD ;
|
|
data PT_LOAD ;
|
|
}
|
|
SECTIONS
|
|
{
|
|
/* Text is loaded with a different VA than data; start with text. */
|
|
#undef LOAD_OFFSET
|
|
#define LOAD_OFFSET TEXT_OFFSET
|
|
|
|
/* Interrupt vectors */
|
|
.intrpt (LOAD_OFFSET) : AT ( 0 ) /* put at the start of physical memory */
|
|
{
|
|
_text = .;
|
|
*(.intrpt)
|
|
} :intrpt =0
|
|
|
|
/* Hypervisor call vectors */
|
|
. = ALIGN(0x10000);
|
|
.hvglue : AT (ADDR(.hvglue) - LOAD_OFFSET) {
|
|
*(.hvglue)
|
|
} :NONE
|
|
|
|
/* Now the real code */
|
|
. = ALIGN(0x20000);
|
|
_stext = .;
|
|
.text : AT (ADDR(.text) - LOAD_OFFSET) {
|
|
HEAD_TEXT
|
|
SCHED_TEXT
|
|
CPUIDLE_TEXT
|
|
LOCK_TEXT
|
|
KPROBES_TEXT
|
|
IRQENTRY_TEXT
|
|
SOFTIRQENTRY_TEXT
|
|
__fix_text_end = .; /* tile-cpack won't rearrange before this */
|
|
ALIGN_FUNCTION();
|
|
*(.hottext*)
|
|
TEXT_TEXT
|
|
*(.text.*)
|
|
*(.coldtext*)
|
|
*(.fixup)
|
|
*(.gnu.warning)
|
|
} :text =0
|
|
_etext = .;
|
|
|
|
/* "Init" is divided into two areas with very different virtual addresses. */
|
|
INIT_TEXT_SECTION(PAGE_SIZE)
|
|
|
|
/*
|
|
* Some things, like the __jump_table, may contain symbol references
|
|
* to __exit text, so include such text in the final image if so.
|
|
* In that case we also override the _einittext from INIT_TEXT_SECTION.
|
|
*/
|
|
#ifdef CONFIG_JUMP_LABEL
|
|
.exit.text : {
|
|
EXIT_TEXT
|
|
_einittext = .;
|
|
}
|
|
#endif
|
|
|
|
/* Now we skip back to PAGE_OFFSET for the data. */
|
|
. = (. - TEXT_OFFSET + PAGE_OFFSET);
|
|
#undef LOAD_OFFSET
|
|
#define LOAD_OFFSET PAGE_OFFSET
|
|
|
|
. = ALIGN(PAGE_SIZE);
|
|
__init_begin = .;
|
|
INIT_DATA_SECTION(16) :data =0
|
|
PERCPU_SECTION(L2_CACHE_BYTES)
|
|
. = ALIGN(PAGE_SIZE);
|
|
__init_end = .;
|
|
|
|
_sdata = .; /* Start of data section */
|
|
RO_DATA_SECTION(PAGE_SIZE)
|
|
RW_DATA_SECTION(L2_CACHE_BYTES, PAGE_SIZE, THREAD_SIZE)
|
|
_edata = .;
|
|
|
|
EXCEPTION_TABLE(L2_CACHE_BYTES)
|
|
NOTES
|
|
|
|
|
|
BSS_SECTION(8, PAGE_SIZE, 1)
|
|
_end = . ;
|
|
|
|
STABS_DEBUG
|
|
DWARF_DEBUG
|
|
|
|
DISCARDS
|
|
}
|