820d41cf0c
Rob Herring has done a sweeping change cleaning up all of the mach/io.h includes, moving some of the oft-repeated macros to a common location and removing a bunch of boiler plate. This is another step closer to a common zImage for multiple platforms. -----BEGIN PGP SIGNATURE----- Version: GnuPG v1.4.11 (GNU/Linux) iQIcBAABAgAGBQJPcpqHAAoJEIwa5zzehBx3xCMP/2evrPQyorzMBztrFB4Ry9Ol qNkSVNsemZjdtkY2dnJv+zJ/Xb0PPDU9EuBHr/SpqmVrRZEZeJND42wZK/OTFCBZ Ufi7KP1qE30daO5H3YmL+58/Ixir5fTHqggqolHhTcEYU2hnHgLBI4rIFu92kSO7 TMyrAUs14jSkTVZc6HSF83w3PfQWhMzWvspJVHQ6RebZRruETAr7v9weVMbgxcDk jQ5XJ9y73rGs2AF8bZTpUdFPzkcac7UiHn3/XyqoZs8RNCL98BGpskzhILyTARf5 X90c9mqQF+AEbb9QSDDd52uYFsJ/5COJvWdlExRI9gZZDI8Pd05ijZBR9IdGJg/B NsVsl98wvZ/zjHJ/Sb2qt5ruet7PiQUGhkshB42jVHsaWfRM030sKGYxQ8pX5Tsa cSagnfBCvAZ9VjDLkXrnEbWRNTz8LSwn9l63z0jmtm5D8+vbpMtgvtWARtuZ4RNn D8wIWoyT0ytVZnosu5441TEgCejtcKOEFzThvKDYMeMJZ/rqVkAbcznapoC2qUd4 fceNlLfQFvW7xpY1MY8mhlwC0ki4hM9MSDieaXUyefvAU/hoSp8MveVUH5UspYfb 0FpkEhzklW/g0/fuq0DJQIrMn7dajjUvVZIUQtiVQuFHOr6RUbFG5vmXuCbAyx10 PE2K4rnKz+PC8bKab7v9 =YIsn -----END PGP SIGNATURE----- Merge tag 'cleanup2' of git://git.kernel.org/pub/scm/linux/kernel/git/arm/arm-soc Pull "ARM: cleanups of io includes" from Olof Johansson: "Rob Herring has done a sweeping change cleaning up all of the mach/io.h includes, moving some of the oft-repeated macros to a common location and removing a bunch of boiler plate. This is another step closer to a common zImage for multiple platforms." Fix up various fairly trivial conflicts (<mach/io.h> removal vs changes around it, tegra localtimer.o is *still* gone, yadda-yadda). * tag 'cleanup2' of git://git.kernel.org/pub/scm/linux/kernel/git/arm/arm-soc: (29 commits) ARM: tegra: Include assembler.h in sleep.S to fix build break ARM: pxa: use common IOMEM definition ARM: dma-mapping: convert ARCH_HAS_DMA_SET_COHERENT_MASK to kconfig symbol ARM: __io abuse cleanup ARM: create a common IOMEM definition ARM: iop13xx: fix missing declaration of iop13xx_init_early ARM: fix ioremap/iounmap for !CONFIG_MMU ARM: kill off __mem_pci ARM: remove bunch of now unused mach/io.h files ARM: make mach/io.h include optional ARM: clps711x: remove unneeded include of mach/io.h ARM: dove: add explicit include of dove.h to addr-map.c ARM: at91: add explicit include of hardware.h to uncompressor ARM: ep93xx: clean-up mach/io.h ARM: tegra: clean-up mach/io.h ARM: orion5x: clean-up mach/io.h ARM: davinci: remove unneeded mach/io.h include [media] davinci: remove includes of mach/io.h ARM: OMAP: Remove remaining includes for mach/io.h ARM: msm: clean-up mach/io.h ...
204 lines
3.3 KiB
ArmAsm
204 lines
3.3 KiB
ArmAsm
/*
|
|
* linux/arch/arm/kernel/debug.S
|
|
*
|
|
* Copyright (C) 1994-1999 Russell King
|
|
*
|
|
* This program is free software; you can redistribute it and/or modify
|
|
* it under the terms of the GNU General Public License version 2 as
|
|
* published by the Free Software Foundation.
|
|
*
|
|
* 32-bit debugging code
|
|
*/
|
|
#include <linux/linkage.h>
|
|
#include <asm/assembler.h>
|
|
|
|
.text
|
|
|
|
/*
|
|
* Some debugging routines (useful if you've got MM problems and
|
|
* printk isn't working). For DEBUGGING ONLY!!! Do not leave
|
|
* references to these in a production kernel!
|
|
*/
|
|
|
|
#if defined(CONFIG_DEBUG_ICEDCC)
|
|
@@ debug using ARM EmbeddedICE DCC channel
|
|
|
|
.macro addruart, rp, rv, tmp
|
|
.endm
|
|
|
|
#if defined(CONFIG_CPU_V6) || defined(CONFIG_CPU_V6K) || defined(CONFIG_CPU_V7)
|
|
|
|
.macro senduart, rd, rx
|
|
mcr p14, 0, \rd, c0, c5, 0
|
|
.endm
|
|
|
|
.macro busyuart, rd, rx
|
|
1001:
|
|
mrc p14, 0, \rx, c0, c1, 0
|
|
tst \rx, #0x20000000
|
|
beq 1001b
|
|
.endm
|
|
|
|
.macro waituart, rd, rx
|
|
mov \rd, #0x2000000
|
|
1001:
|
|
subs \rd, \rd, #1
|
|
bmi 1002f
|
|
mrc p14, 0, \rx, c0, c1, 0
|
|
tst \rx, #0x20000000
|
|
bne 1001b
|
|
1002:
|
|
.endm
|
|
|
|
#elif defined(CONFIG_CPU_XSCALE)
|
|
|
|
.macro senduart, rd, rx
|
|
mcr p14, 0, \rd, c8, c0, 0
|
|
.endm
|
|
|
|
.macro busyuart, rd, rx
|
|
1001:
|
|
mrc p14, 0, \rx, c14, c0, 0
|
|
tst \rx, #0x10000000
|
|
beq 1001b
|
|
.endm
|
|
|
|
.macro waituart, rd, rx
|
|
mov \rd, #0x10000000
|
|
1001:
|
|
subs \rd, \rd, #1
|
|
bmi 1002f
|
|
mrc p14, 0, \rx, c14, c0, 0
|
|
tst \rx, #0x10000000
|
|
bne 1001b
|
|
1002:
|
|
.endm
|
|
|
|
#else
|
|
|
|
.macro senduart, rd, rx
|
|
mcr p14, 0, \rd, c1, c0, 0
|
|
.endm
|
|
|
|
.macro busyuart, rd, rx
|
|
1001:
|
|
mrc p14, 0, \rx, c0, c0, 0
|
|
tst \rx, #2
|
|
beq 1001b
|
|
|
|
.endm
|
|
|
|
.macro waituart, rd, rx
|
|
mov \rd, #0x2000000
|
|
1001:
|
|
subs \rd, \rd, #1
|
|
bmi 1002f
|
|
mrc p14, 0, \rx, c0, c0, 0
|
|
tst \rx, #2
|
|
bne 1001b
|
|
1002:
|
|
.endm
|
|
|
|
#endif /* CONFIG_CPU_V6 */
|
|
|
|
#elif !defined(CONFIG_DEBUG_SEMIHOSTING)
|
|
#include <mach/debug-macro.S>
|
|
#endif /* CONFIG_DEBUG_ICEDCC */
|
|
|
|
#ifdef CONFIG_MMU
|
|
.macro addruart_current, rx, tmp1, tmp2
|
|
addruart \tmp1, \tmp2, \rx
|
|
mrc p15, 0, \rx, c1, c0
|
|
tst \rx, #1
|
|
moveq \rx, \tmp1
|
|
movne \rx, \tmp2
|
|
.endm
|
|
|
|
#else /* !CONFIG_MMU */
|
|
.macro addruart_current, rx, tmp1, tmp2
|
|
addruart \rx, \tmp1
|
|
.endm
|
|
|
|
#endif /* CONFIG_MMU */
|
|
|
|
/*
|
|
* Useful debugging routines
|
|
*/
|
|
ENTRY(printhex8)
|
|
mov r1, #8
|
|
b printhex
|
|
ENDPROC(printhex8)
|
|
|
|
ENTRY(printhex4)
|
|
mov r1, #4
|
|
b printhex
|
|
ENDPROC(printhex4)
|
|
|
|
ENTRY(printhex2)
|
|
mov r1, #2
|
|
printhex: adr r2, hexbuf
|
|
add r3, r2, r1
|
|
mov r1, #0
|
|
strb r1, [r3]
|
|
1: and r1, r0, #15
|
|
mov r0, r0, lsr #4
|
|
cmp r1, #10
|
|
addlt r1, r1, #'0'
|
|
addge r1, r1, #'a' - 10
|
|
strb r1, [r3, #-1]!
|
|
teq r3, r2
|
|
bne 1b
|
|
mov r0, r2
|
|
b printascii
|
|
ENDPROC(printhex2)
|
|
|
|
hexbuf: .space 16
|
|
|
|
.ltorg
|
|
|
|
#ifndef CONFIG_DEBUG_SEMIHOSTING
|
|
|
|
ENTRY(printascii)
|
|
addruart_current r3, r1, r2
|
|
b 2f
|
|
1: waituart r2, r3
|
|
senduart r1, r3
|
|
busyuart r2, r3
|
|
teq r1, #'\n'
|
|
moveq r1, #'\r'
|
|
beq 1b
|
|
2: teq r0, #0
|
|
ldrneb r1, [r0], #1
|
|
teqne r1, #0
|
|
bne 1b
|
|
mov pc, lr
|
|
ENDPROC(printascii)
|
|
|
|
ENTRY(printch)
|
|
addruart_current r3, r1, r2
|
|
mov r1, r0
|
|
mov r0, #0
|
|
b 1b
|
|
ENDPROC(printch)
|
|
|
|
#else
|
|
|
|
ENTRY(printascii)
|
|
mov r1, r0
|
|
mov r0, #0x04 @ SYS_WRITE0
|
|
ARM( svc #0x123456 )
|
|
THUMB( svc #0xab )
|
|
mov pc, lr
|
|
ENDPROC(printascii)
|
|
|
|
ENTRY(printch)
|
|
adr r1, hexbuf
|
|
strb r0, [r1]
|
|
mov r0, #0x03 @ SYS_WRITEC
|
|
ARM( svc #0x123456 )
|
|
THUMB( svc #0xab )
|
|
mov pc, lr
|
|
ENDPROC(printch)
|
|
|
|
#endif
|