b24413180f
Many source files in the tree are missing licensing information, which makes it harder for compliance tools to determine the correct license. By default all files without license information are under the default license of the kernel, which is GPL version 2. Update the files which contain no license information with the 'GPL-2.0' SPDX license identifier. The SPDX identifier is a legally binding shorthand, which can be used instead of the full boiler plate text. This patch is based on work done by Thomas Gleixner and Kate Stewart and Philippe Ombredanne. How this work was done: Patches were generated and checked against linux-4.14-rc6 for a subset of the use cases: - file had no licensing information it it. - file was a */uapi/* one with no licensing information in it, - file was a */uapi/* one with existing licensing information, Further patches will be generated in subsequent months to fix up cases where non-standard license headers were used, and references to license had to be inferred by heuristics based on keywords. The analysis to determine which SPDX License Identifier to be applied to a file was done in a spreadsheet of side by side results from of the output of two independent scanners (ScanCode & Windriver) producing SPDX tag:value files created by Philippe Ombredanne. Philippe prepared the base worksheet, and did an initial spot review of a few 1000 files. The 4.13 kernel was the starting point of the analysis with 60,537 files assessed. Kate Stewart did a file by file comparison of the scanner results in the spreadsheet to determine which SPDX license identifier(s) to be applied to the file. She confirmed any determination that was not immediately clear with lawyers working with the Linux Foundation. Criteria used to select files for SPDX license identifier tagging was: - Files considered eligible had to be source code files. - Make and config files were included as candidates if they contained >5 lines of source - File already had some variant of a license header in it (even if <5 lines). All documentation files were explicitly excluded. The following heuristics were used to determine which SPDX license identifiers to apply. - when both scanners couldn't find any license traces, file was considered to have no license information in it, and the top level COPYING file license applied. For non */uapi/* files that summary was: SPDX license identifier # files ---------------------------------------------------|------- GPL-2.0 11139 and resulted in the first patch in this series. If that file was a */uapi/* path one, it was "GPL-2.0 WITH Linux-syscall-note" otherwise it was "GPL-2.0". Results of that was: SPDX license identifier # files ---------------------------------------------------|------- GPL-2.0 WITH Linux-syscall-note 930 and resulted in the second patch in this series. - if a file had some form of licensing information in it, and was one of the */uapi/* ones, it was denoted with the Linux-syscall-note if any GPL family license was found in the file or had no licensing in it (per prior point). Results summary: SPDX license identifier # files ---------------------------------------------------|------ GPL-2.0 WITH Linux-syscall-note 270 GPL-2.0+ WITH Linux-syscall-note 169 ((GPL-2.0 WITH Linux-syscall-note) OR BSD-2-Clause) 21 ((GPL-2.0 WITH Linux-syscall-note) OR BSD-3-Clause) 17 LGPL-2.1+ WITH Linux-syscall-note 15 GPL-1.0+ WITH Linux-syscall-note 14 ((GPL-2.0+ WITH Linux-syscall-note) OR BSD-3-Clause) 5 LGPL-2.0+ WITH Linux-syscall-note 4 LGPL-2.1 WITH Linux-syscall-note 3 ((GPL-2.0 WITH Linux-syscall-note) OR MIT) 3 ((GPL-2.0 WITH Linux-syscall-note) AND MIT) 1 and that resulted in the third patch in this series. - when the two scanners agreed on the detected license(s), that became the concluded license(s). - when there was disagreement between the two scanners (one detected a license but the other didn't, or they both detected different licenses) a manual inspection of the file occurred. - In most cases a manual inspection of the information in the file resulted in a clear resolution of the license that should apply (and which scanner probably needed to revisit its heuristics). - When it was not immediately clear, the license identifier was confirmed with lawyers working with the Linux Foundation. - If there was any question as to the appropriate license identifier, the file was flagged for further research and to be revisited later in time. In total, over 70 hours of logged manual review was done on the spreadsheet to determine the SPDX license identifiers to apply to the source files by Kate, Philippe, Thomas and, in some cases, confirmation by lawyers working with the Linux Foundation. Kate also obtained a third independent scan of the 4.13 code base from FOSSology, and compared selected files where the other two scanners disagreed against that SPDX file, to see if there was new insights. The Windriver scanner is based on an older version of FOSSology in part, so they are related. Thomas did random spot checks in about 500 files from the spreadsheets for the uapi headers and agreed with SPDX license identifier in the files he inspected. For the non-uapi files Thomas did random spot checks in about 15000 files. In initial set of patches against 4.14-rc6, 3 files were found to have copy/paste license identifier errors, and have been fixed to reflect the correct identifier. Additionally Philippe spent 10 hours this week doing a detailed manual inspection and review of the 12,461 patched files from the initial patch version early this week with: - a full scancode scan run, collecting the matched texts, detected license ids and scores - reviewing anything where there was a license detected (about 500+ files) to ensure that the applied SPDX license was correct - reviewing anything where there was no detection but the patch license was not GPL-2.0 WITH Linux-syscall-note to ensure that the applied SPDX license was correct This produced a worksheet with 20 files needing minor correction. This worksheet was then exported into 3 different .csv files for the different types of files to be modified. These .csv files were then reviewed by Greg. Thomas wrote a script to parse the csv files and add the proper SPDX tag to the file, in the format that the file expected. This script was further refined by Greg based on the output to detect more types of files automatically and to distinguish between header and source .c files (which need different comment types.) Finally Greg ran the script using the .csv files to generate the patches. Reviewed-by: Kate Stewart <kstewart@linuxfoundation.org> Reviewed-by: Philippe Ombredanne <pombredanne@nexb.com> Reviewed-by: Thomas Gleixner <tglx@linutronix.de> Signed-off-by: Greg Kroah-Hartman <gregkh@linuxfoundation.org>
157 lines
4.1 KiB
ArmAsm
157 lines
4.1 KiB
ArmAsm
/* SPDX-License-Identifier: GPL-2.0 */
|
|
#include <linux/linkage.h>
|
|
#include <asm/segment.h>
|
|
#include <asm/page_types.h>
|
|
#include <asm/processor-flags.h>
|
|
#include <asm/msr-index.h>
|
|
#include "realmode.h"
|
|
|
|
/*
|
|
* The following code and data reboots the machine by switching to real
|
|
* mode and jumping to the BIOS reset entry point, as if the CPU has
|
|
* really been reset. The previous version asked the keyboard
|
|
* controller to pulse the CPU reset line, which is more thorough, but
|
|
* doesn't work with at least one type of 486 motherboard. It is easy
|
|
* to stop this code working; hence the copious comments.
|
|
*
|
|
* This code is called with the restart type (0 = BIOS, 1 = APM) in
|
|
* the primary argument register (%eax for 32 bit, %edi for 64 bit).
|
|
*/
|
|
.section ".text32", "ax"
|
|
.code32
|
|
ENTRY(machine_real_restart_asm)
|
|
|
|
#ifdef CONFIG_X86_64
|
|
/* Switch to trampoline GDT as it is guaranteed < 4 GiB */
|
|
movl $__KERNEL_DS, %eax
|
|
movl %eax, %ds
|
|
lgdtl pa_tr_gdt
|
|
|
|
/* Disable paging to drop us out of long mode */
|
|
movl %cr0, %eax
|
|
andl $~X86_CR0_PG, %eax
|
|
movl %eax, %cr0
|
|
ljmpl $__KERNEL32_CS, $pa_machine_real_restart_paging_off
|
|
|
|
GLOBAL(machine_real_restart_paging_off)
|
|
xorl %eax, %eax
|
|
xorl %edx, %edx
|
|
movl $MSR_EFER, %ecx
|
|
wrmsr
|
|
|
|
movl %edi, %eax
|
|
|
|
#endif /* CONFIG_X86_64 */
|
|
|
|
/* Set up the IDT for real mode. */
|
|
lidtl pa_machine_real_restart_idt
|
|
|
|
/*
|
|
* Set up a GDT from which we can load segment descriptors for real
|
|
* mode. The GDT is not used in real mode; it is just needed here to
|
|
* prepare the descriptors.
|
|
*/
|
|
lgdtl pa_machine_real_restart_gdt
|
|
|
|
/*
|
|
* Load the data segment registers with 16-bit compatible values
|
|
*/
|
|
movl $16, %ecx
|
|
movl %ecx, %ds
|
|
movl %ecx, %es
|
|
movl %ecx, %fs
|
|
movl %ecx, %gs
|
|
movl %ecx, %ss
|
|
ljmpw $8, $1f
|
|
|
|
/*
|
|
* This is 16-bit protected mode code to disable paging and the cache,
|
|
* switch to real mode and jump to the BIOS reset code.
|
|
*
|
|
* The instruction that switches to real mode by writing to CR0 must be
|
|
* followed immediately by a far jump instruction, which set CS to a
|
|
* valid value for real mode, and flushes the prefetch queue to avoid
|
|
* running instructions that have already been decoded in protected
|
|
* mode.
|
|
*
|
|
* Clears all the flags except ET, especially PG (paging), PE
|
|
* (protected-mode enable) and TS (task switch for coprocessor state
|
|
* save). Flushes the TLB after paging has been disabled. Sets CD and
|
|
* NW, to disable the cache on a 486, and invalidates the cache. This
|
|
* is more like the state of a 486 after reset. I don't know if
|
|
* something else should be done for other chips.
|
|
*
|
|
* More could be done here to set up the registers as if a CPU reset had
|
|
* occurred; hopefully real BIOSs don't assume much. This is not the
|
|
* actual BIOS entry point, anyway (that is at 0xfffffff0).
|
|
*
|
|
* Most of this work is probably excessive, but it is what is tested.
|
|
*/
|
|
.text
|
|
.code16
|
|
|
|
.balign 16
|
|
machine_real_restart_asm16:
|
|
1:
|
|
xorl %ecx, %ecx
|
|
movl %cr0, %edx
|
|
andl $0x00000011, %edx
|
|
orl $0x60000000, %edx
|
|
movl %edx, %cr0
|
|
movl %ecx, %cr3
|
|
movl %cr0, %edx
|
|
testl $0x60000000, %edx /* If no cache bits -> no wbinvd */
|
|
jz 2f
|
|
wbinvd
|
|
2:
|
|
andb $0x10, %dl
|
|
movl %edx, %cr0
|
|
LJMPW_RM(3f)
|
|
3:
|
|
andw %ax, %ax
|
|
jz bios
|
|
|
|
apm:
|
|
movw $0x1000, %ax
|
|
movw %ax, %ss
|
|
movw $0xf000, %sp
|
|
movw $0x5307, %ax
|
|
movw $0x0001, %bx
|
|
movw $0x0003, %cx
|
|
int $0x15
|
|
/* This should never return... */
|
|
|
|
bios:
|
|
ljmpw $0xf000, $0xfff0
|
|
|
|
.section ".rodata", "a"
|
|
|
|
.balign 16
|
|
GLOBAL(machine_real_restart_idt)
|
|
.word 0xffff /* Length - real mode default value */
|
|
.long 0 /* Base - real mode default value */
|
|
END(machine_real_restart_idt)
|
|
|
|
.balign 16
|
|
GLOBAL(machine_real_restart_gdt)
|
|
/* Self-pointer */
|
|
.word 0xffff /* Length - real mode default value */
|
|
.long pa_machine_real_restart_gdt
|
|
.word 0
|
|
|
|
/*
|
|
* 16-bit code segment pointing to real_mode_seg
|
|
* Selector value 8
|
|
*/
|
|
.word 0xffff /* Limit */
|
|
.long 0x9b000000 + pa_real_mode_base
|
|
.word 0
|
|
|
|
/*
|
|
* 16-bit data segment with the selector value 16 = 0x10 and
|
|
* base value 0x100; since this is consistent with real mode
|
|
* semantics we don't have to reload the segments once CR0.PE = 0.
|
|
*/
|
|
.quad GDT_ENTRY(0x0093, 0x100, 0xffff)
|
|
END(machine_real_restart_gdt)
|