![Fabio Estevam](/assets/img/avatar_default.png)
According to Documentation/SubmittingPatches: "Describe your changes in imperative mood, e.g. "make xyzzy do frotz" instead of "[This patch] makes xyzzy do frotz" or "[I] changed xyzzy to do frotz", as if you are giving orders to the codebase to change its behaviour." So do as recommended. Signed-off-by: Fabio Estevam <fabio.estevam@freescale.com> Acked-by: Julia Lawall <julia.lawall@lip6.fr> Signed-off-by: Michal Marek <mmarek@suse.cz>
67 lines
1.2 KiB
Plaintext
67 lines
1.2 KiB
Plaintext
///
|
|
/// Remove unneeded variable used to store return value.
|
|
///
|
|
// Confidence: Moderate
|
|
// Copyright: (C) 2012 Peter Senna Tschudin, INRIA/LIP6. GPLv2.
|
|
// URL: http://coccinelle.lip6.fr/
|
|
// Comments: Comments on code can be deleted if near code that is removed.
|
|
// "when strict" can be removed to get more hits, but adds false
|
|
// positives
|
|
// Options: --no-includes --include-headers
|
|
|
|
virtual patch
|
|
virtual report
|
|
virtual context
|
|
virtual org
|
|
|
|
@depends on patch@
|
|
type T;
|
|
constant C;
|
|
identifier ret;
|
|
@@
|
|
- T ret = C;
|
|
... when != ret
|
|
when strict
|
|
return
|
|
- ret
|
|
+ C
|
|
;
|
|
|
|
@depends on context@
|
|
type T;
|
|
constant C;
|
|
identifier ret;
|
|
@@
|
|
* T ret = C;
|
|
... when != ret
|
|
when strict
|
|
* return ret;
|
|
|
|
@r1 depends on report || org@
|
|
type T;
|
|
constant C;
|
|
identifier ret;
|
|
position p1, p2;
|
|
@@
|
|
T ret@p1 = C;
|
|
... when != ret
|
|
when strict
|
|
return ret@p2;
|
|
|
|
@script:python depends on report@
|
|
p1 << r1.p1;
|
|
p2 << r1.p2;
|
|
C << r1.C;
|
|
ret << r1.ret;
|
|
@@
|
|
coccilib.report.print_report(p1[0], "Unneeded variable: \"" + ret + "\". Return \"" + C + "\" on line " + p2[0].line)
|
|
|
|
@script:python depends on org@
|
|
p1 << r1.p1;
|
|
p2 << r1.p2;
|
|
C << r1.C;
|
|
ret << r1.ret;
|
|
@@
|
|
cocci.print_main("unneeded \"" + ret + "\" variable", p1)
|
|
cocci.print_sec("return " + C + " here", p2)
|