![Greg Kroah-Hartman](/assets/img/avatar_default.png)
Many source files in the tree are missing licensing information, which makes it harder for compliance tools to determine the correct license. By default all files without license information are under the default license of the kernel, which is GPL version 2. Update the files which contain no license information with the 'GPL-2.0' SPDX license identifier. The SPDX identifier is a legally binding shorthand, which can be used instead of the full boiler plate text. This patch is based on work done by Thomas Gleixner and Kate Stewart and Philippe Ombredanne. How this work was done: Patches were generated and checked against linux-4.14-rc6 for a subset of the use cases: - file had no licensing information it it. - file was a */uapi/* one with no licensing information in it, - file was a */uapi/* one with existing licensing information, Further patches will be generated in subsequent months to fix up cases where non-standard license headers were used, and references to license had to be inferred by heuristics based on keywords. The analysis to determine which SPDX License Identifier to be applied to a file was done in a spreadsheet of side by side results from of the output of two independent scanners (ScanCode & Windriver) producing SPDX tag:value files created by Philippe Ombredanne. Philippe prepared the base worksheet, and did an initial spot review of a few 1000 files. The 4.13 kernel was the starting point of the analysis with 60,537 files assessed. Kate Stewart did a file by file comparison of the scanner results in the spreadsheet to determine which SPDX license identifier(s) to be applied to the file. She confirmed any determination that was not immediately clear with lawyers working with the Linux Foundation. Criteria used to select files for SPDX license identifier tagging was: - Files considered eligible had to be source code files. - Make and config files were included as candidates if they contained >5 lines of source - File already had some variant of a license header in it (even if <5 lines). All documentation files were explicitly excluded. The following heuristics were used to determine which SPDX license identifiers to apply. - when both scanners couldn't find any license traces, file was considered to have no license information in it, and the top level COPYING file license applied. For non */uapi/* files that summary was: SPDX license identifier # files ---------------------------------------------------|------- GPL-2.0 11139 and resulted in the first patch in this series. If that file was a */uapi/* path one, it was "GPL-2.0 WITH Linux-syscall-note" otherwise it was "GPL-2.0". Results of that was: SPDX license identifier # files ---------------------------------------------------|------- GPL-2.0 WITH Linux-syscall-note 930 and resulted in the second patch in this series. - if a file had some form of licensing information in it, and was one of the */uapi/* ones, it was denoted with the Linux-syscall-note if any GPL family license was found in the file or had no licensing in it (per prior point). Results summary: SPDX license identifier # files ---------------------------------------------------|------ GPL-2.0 WITH Linux-syscall-note 270 GPL-2.0+ WITH Linux-syscall-note 169 ((GPL-2.0 WITH Linux-syscall-note) OR BSD-2-Clause) 21 ((GPL-2.0 WITH Linux-syscall-note) OR BSD-3-Clause) 17 LGPL-2.1+ WITH Linux-syscall-note 15 GPL-1.0+ WITH Linux-syscall-note 14 ((GPL-2.0+ WITH Linux-syscall-note) OR BSD-3-Clause) 5 LGPL-2.0+ WITH Linux-syscall-note 4 LGPL-2.1 WITH Linux-syscall-note 3 ((GPL-2.0 WITH Linux-syscall-note) OR MIT) 3 ((GPL-2.0 WITH Linux-syscall-note) AND MIT) 1 and that resulted in the third patch in this series. - when the two scanners agreed on the detected license(s), that became the concluded license(s). - when there was disagreement between the two scanners (one detected a license but the other didn't, or they both detected different licenses) a manual inspection of the file occurred. - In most cases a manual inspection of the information in the file resulted in a clear resolution of the license that should apply (and which scanner probably needed to revisit its heuristics). - When it was not immediately clear, the license identifier was confirmed with lawyers working with the Linux Foundation. - If there was any question as to the appropriate license identifier, the file was flagged for further research and to be revisited later in time. In total, over 70 hours of logged manual review was done on the spreadsheet to determine the SPDX license identifiers to apply to the source files by Kate, Philippe, Thomas and, in some cases, confirmation by lawyers working with the Linux Foundation. Kate also obtained a third independent scan of the 4.13 code base from FOSSology, and compared selected files where the other two scanners disagreed against that SPDX file, to see if there was new insights. The Windriver scanner is based on an older version of FOSSology in part, so they are related. Thomas did random spot checks in about 500 files from the spreadsheets for the uapi headers and agreed with SPDX license identifier in the files he inspected. For the non-uapi files Thomas did random spot checks in about 15000 files. In initial set of patches against 4.14-rc6, 3 files were found to have copy/paste license identifier errors, and have been fixed to reflect the correct identifier. Additionally Philippe spent 10 hours this week doing a detailed manual inspection and review of the 12,461 patched files from the initial patch version early this week with: - a full scancode scan run, collecting the matched texts, detected license ids and scores - reviewing anything where there was a license detected (about 500+ files) to ensure that the applied SPDX license was correct - reviewing anything where there was no detection but the patch license was not GPL-2.0 WITH Linux-syscall-note to ensure that the applied SPDX license was correct This produced a worksheet with 20 files needing minor correction. This worksheet was then exported into 3 different .csv files for the different types of files to be modified. These .csv files were then reviewed by Greg. Thomas wrote a script to parse the csv files and add the proper SPDX tag to the file, in the format that the file expected. This script was further refined by Greg based on the output to detect more types of files automatically and to distinguish between header and source .c files (which need different comment types.) Finally Greg ran the script using the .csv files to generate the patches. Reviewed-by: Kate Stewart <kstewart@linuxfoundation.org> Reviewed-by: Philippe Ombredanne <pombredanne@nexb.com> Reviewed-by: Thomas Gleixner <tglx@linutronix.de> Signed-off-by: Greg Kroah-Hartman <gregkh@linuxfoundation.org>
206 lines
4.2 KiB
ArmAsm
206 lines
4.2 KiB
ArmAsm
/* SPDX-License-Identifier: GPL-2.0 */
|
|
/*
|
|
* arch/alpha/lib/ev6-copy_page.S
|
|
*
|
|
* Copy an entire page.
|
|
*/
|
|
|
|
/* The following comparison of this routine vs the normal copy_page.S
|
|
was written by an unnamed ev6 hardware designer and forwarded to me
|
|
via Steven Hobbs <hobbs@steven.zko.dec.com>.
|
|
|
|
First Problem: STQ overflows.
|
|
-----------------------------
|
|
|
|
It would be nice if EV6 handled every resource overflow efficiently,
|
|
but for some it doesn't. Including store queue overflows. It causes
|
|
a trap and a restart of the pipe.
|
|
|
|
To get around this we sometimes use (to borrow a term from a VSSAD
|
|
researcher) "aeration". The idea is to slow the rate at which the
|
|
processor receives valid instructions by inserting nops in the fetch
|
|
path. In doing so, you can prevent the overflow and actually make
|
|
the code run faster. You can, of course, take advantage of the fact
|
|
that the processor can fetch at most 4 aligned instructions per cycle.
|
|
|
|
I inserted enough nops to force it to take 10 cycles to fetch the
|
|
loop code. In theory, EV6 should be able to execute this loop in
|
|
9 cycles but I was not able to get it to run that fast -- the initial
|
|
conditions were such that I could not reach this optimum rate on
|
|
(chaotic) EV6. I wrote the code such that everything would issue
|
|
in order.
|
|
|
|
Second Problem: Dcache index matches.
|
|
-------------------------------------
|
|
|
|
If you are going to use this routine on random aligned pages, there
|
|
is a 25% chance that the pages will be at the same dcache indices.
|
|
This results in many nasty memory traps without care.
|
|
|
|
The solution is to schedule the prefetches to avoid the memory
|
|
conflicts. I schedule the wh64 prefetches farther ahead of the
|
|
read prefetches to avoid this problem.
|
|
|
|
Third Problem: Needs more prefetching.
|
|
--------------------------------------
|
|
|
|
In order to improve the code I added deeper prefetching to take the
|
|
most advantage of EV6's bandwidth.
|
|
|
|
I also prefetched the read stream. Note that adding the read prefetch
|
|
forced me to add another cycle to the inner-most kernel - up to 11
|
|
from the original 8 cycles per iteration. We could improve performance
|
|
further by unrolling the loop and doing multiple prefetches per cycle.
|
|
|
|
I think that the code below will be very robust and fast code for the
|
|
purposes of copying aligned pages. It is slower when both source and
|
|
destination pages are in the dcache, but it is my guess that this is
|
|
less important than the dcache miss case. */
|
|
|
|
#include <asm/export.h>
|
|
.text
|
|
.align 4
|
|
.global copy_page
|
|
.ent copy_page
|
|
copy_page:
|
|
.prologue 0
|
|
|
|
/* Prefetch 5 read cachelines; write-hint 10 cache lines. */
|
|
wh64 ($16)
|
|
ldl $31,0($17)
|
|
ldl $31,64($17)
|
|
lda $1,1*64($16)
|
|
|
|
wh64 ($1)
|
|
ldl $31,128($17)
|
|
ldl $31,192($17)
|
|
lda $1,2*64($16)
|
|
|
|
wh64 ($1)
|
|
ldl $31,256($17)
|
|
lda $18,118
|
|
lda $1,3*64($16)
|
|
|
|
wh64 ($1)
|
|
nop
|
|
lda $1,4*64($16)
|
|
lda $2,5*64($16)
|
|
|
|
wh64 ($1)
|
|
wh64 ($2)
|
|
lda $1,6*64($16)
|
|
lda $2,7*64($16)
|
|
|
|
wh64 ($1)
|
|
wh64 ($2)
|
|
lda $1,8*64($16)
|
|
lda $2,9*64($16)
|
|
|
|
wh64 ($1)
|
|
wh64 ($2)
|
|
lda $19,10*64($16)
|
|
nop
|
|
|
|
/* Main prefetching/write-hinting loop. */
|
|
1: ldq $0,0($17)
|
|
ldq $1,8($17)
|
|
unop
|
|
unop
|
|
|
|
unop
|
|
unop
|
|
ldq $2,16($17)
|
|
ldq $3,24($17)
|
|
|
|
ldq $4,32($17)
|
|
ldq $5,40($17)
|
|
unop
|
|
unop
|
|
|
|
unop
|
|
unop
|
|
ldq $6,48($17)
|
|
ldq $7,56($17)
|
|
|
|
ldl $31,320($17)
|
|
unop
|
|
unop
|
|
unop
|
|
|
|
/* This gives the extra cycle of aeration above the minimum. */
|
|
unop
|
|
unop
|
|
unop
|
|
unop
|
|
|
|
wh64 ($19)
|
|
unop
|
|
unop
|
|
unop
|
|
|
|
stq $0,0($16)
|
|
subq $18,1,$18
|
|
stq $1,8($16)
|
|
unop
|
|
|
|
unop
|
|
stq $2,16($16)
|
|
addq $17,64,$17
|
|
stq $3,24($16)
|
|
|
|
stq $4,32($16)
|
|
stq $5,40($16)
|
|
addq $19,64,$19
|
|
unop
|
|
|
|
stq $6,48($16)
|
|
stq $7,56($16)
|
|
addq $16,64,$16
|
|
bne $18, 1b
|
|
|
|
/* Prefetch the final 5 cache lines of the read stream. */
|
|
lda $18,10
|
|
ldl $31,320($17)
|
|
ldl $31,384($17)
|
|
ldl $31,448($17)
|
|
|
|
ldl $31,512($17)
|
|
ldl $31,576($17)
|
|
nop
|
|
nop
|
|
|
|
/* Non-prefetching, non-write-hinting cleanup loop for the
|
|
final 10 cache lines. */
|
|
2: ldq $0,0($17)
|
|
ldq $1,8($17)
|
|
ldq $2,16($17)
|
|
ldq $3,24($17)
|
|
|
|
ldq $4,32($17)
|
|
ldq $5,40($17)
|
|
ldq $6,48($17)
|
|
ldq $7,56($17)
|
|
|
|
stq $0,0($16)
|
|
subq $18,1,$18
|
|
stq $1,8($16)
|
|
addq $17,64,$17
|
|
|
|
stq $2,16($16)
|
|
stq $3,24($16)
|
|
stq $4,32($16)
|
|
stq $5,40($16)
|
|
|
|
stq $6,48($16)
|
|
stq $7,56($16)
|
|
addq $16,64,$16
|
|
bne $18, 2b
|
|
|
|
ret
|
|
nop
|
|
unop
|
|
nop
|
|
|
|
.end copy_page
|
|
EXPORT_SYMBOL(copy_page)
|