b24413180f
Many source files in the tree are missing licensing information, which makes it harder for compliance tools to determine the correct license. By default all files without license information are under the default license of the kernel, which is GPL version 2. Update the files which contain no license information with the 'GPL-2.0' SPDX license identifier. The SPDX identifier is a legally binding shorthand, which can be used instead of the full boiler plate text. This patch is based on work done by Thomas Gleixner and Kate Stewart and Philippe Ombredanne. How this work was done: Patches were generated and checked against linux-4.14-rc6 for a subset of the use cases: - file had no licensing information it it. - file was a */uapi/* one with no licensing information in it, - file was a */uapi/* one with existing licensing information, Further patches will be generated in subsequent months to fix up cases where non-standard license headers were used, and references to license had to be inferred by heuristics based on keywords. The analysis to determine which SPDX License Identifier to be applied to a file was done in a spreadsheet of side by side results from of the output of two independent scanners (ScanCode & Windriver) producing SPDX tag:value files created by Philippe Ombredanne. Philippe prepared the base worksheet, and did an initial spot review of a few 1000 files. The 4.13 kernel was the starting point of the analysis with 60,537 files assessed. Kate Stewart did a file by file comparison of the scanner results in the spreadsheet to determine which SPDX license identifier(s) to be applied to the file. She confirmed any determination that was not immediately clear with lawyers working with the Linux Foundation. Criteria used to select files for SPDX license identifier tagging was: - Files considered eligible had to be source code files. - Make and config files were included as candidates if they contained >5 lines of source - File already had some variant of a license header in it (even if <5 lines). All documentation files were explicitly excluded. The following heuristics were used to determine which SPDX license identifiers to apply. - when both scanners couldn't find any license traces, file was considered to have no license information in it, and the top level COPYING file license applied. For non */uapi/* files that summary was: SPDX license identifier # files ---------------------------------------------------|------- GPL-2.0 11139 and resulted in the first patch in this series. If that file was a */uapi/* path one, it was "GPL-2.0 WITH Linux-syscall-note" otherwise it was "GPL-2.0". Results of that was: SPDX license identifier # files ---------------------------------------------------|------- GPL-2.0 WITH Linux-syscall-note 930 and resulted in the second patch in this series. - if a file had some form of licensing information in it, and was one of the */uapi/* ones, it was denoted with the Linux-syscall-note if any GPL family license was found in the file or had no licensing in it (per prior point). Results summary: SPDX license identifier # files ---------------------------------------------------|------ GPL-2.0 WITH Linux-syscall-note 270 GPL-2.0+ WITH Linux-syscall-note 169 ((GPL-2.0 WITH Linux-syscall-note) OR BSD-2-Clause) 21 ((GPL-2.0 WITH Linux-syscall-note) OR BSD-3-Clause) 17 LGPL-2.1+ WITH Linux-syscall-note 15 GPL-1.0+ WITH Linux-syscall-note 14 ((GPL-2.0+ WITH Linux-syscall-note) OR BSD-3-Clause) 5 LGPL-2.0+ WITH Linux-syscall-note 4 LGPL-2.1 WITH Linux-syscall-note 3 ((GPL-2.0 WITH Linux-syscall-note) OR MIT) 3 ((GPL-2.0 WITH Linux-syscall-note) AND MIT) 1 and that resulted in the third patch in this series. - when the two scanners agreed on the detected license(s), that became the concluded license(s). - when there was disagreement between the two scanners (one detected a license but the other didn't, or they both detected different licenses) a manual inspection of the file occurred. - In most cases a manual inspection of the information in the file resulted in a clear resolution of the license that should apply (and which scanner probably needed to revisit its heuristics). - When it was not immediately clear, the license identifier was confirmed with lawyers working with the Linux Foundation. - If there was any question as to the appropriate license identifier, the file was flagged for further research and to be revisited later in time. In total, over 70 hours of logged manual review was done on the spreadsheet to determine the SPDX license identifiers to apply to the source files by Kate, Philippe, Thomas and, in some cases, confirmation by lawyers working with the Linux Foundation. Kate also obtained a third independent scan of the 4.13 code base from FOSSology, and compared selected files where the other two scanners disagreed against that SPDX file, to see if there was new insights. The Windriver scanner is based on an older version of FOSSology in part, so they are related. Thomas did random spot checks in about 500 files from the spreadsheets for the uapi headers and agreed with SPDX license identifier in the files he inspected. For the non-uapi files Thomas did random spot checks in about 15000 files. In initial set of patches against 4.14-rc6, 3 files were found to have copy/paste license identifier errors, and have been fixed to reflect the correct identifier. Additionally Philippe spent 10 hours this week doing a detailed manual inspection and review of the 12,461 patched files from the initial patch version early this week with: - a full scancode scan run, collecting the matched texts, detected license ids and scores - reviewing anything where there was a license detected (about 500+ files) to ensure that the applied SPDX license was correct - reviewing anything where there was no detection but the patch license was not GPL-2.0 WITH Linux-syscall-note to ensure that the applied SPDX license was correct This produced a worksheet with 20 files needing minor correction. This worksheet was then exported into 3 different .csv files for the different types of files to be modified. These .csv files were then reviewed by Greg. Thomas wrote a script to parse the csv files and add the proper SPDX tag to the file, in the format that the file expected. This script was further refined by Greg based on the output to detect more types of files automatically and to distinguish between header and source .c files (which need different comment types.) Finally Greg ran the script using the .csv files to generate the patches. Reviewed-by: Kate Stewart <kstewart@linuxfoundation.org> Reviewed-by: Philippe Ombredanne <pombredanne@nexb.com> Reviewed-by: Thomas Gleixner <tglx@linutronix.de> Signed-off-by: Greg Kroah-Hartman <gregkh@linuxfoundation.org>
187 lines
4.8 KiB
ArmAsm
187 lines
4.8 KiB
ArmAsm
! SPDX-License-Identifier: GPL-2.0
|
|
! Copyright (C) 2008-2012 Imagination Technologies Ltd.
|
|
|
|
.text
|
|
.global _memcpy
|
|
.type _memcpy,function
|
|
! D1Ar1 dst
|
|
! D0Ar2 src
|
|
! D1Ar3 cnt
|
|
! D0Re0 dst
|
|
_memcpy:
|
|
CMP D1Ar3, #16
|
|
MOV A1.2, D0Ar2 ! source pointer
|
|
MOV A0.2, D1Ar1 ! destination pointer
|
|
MOV A0.3, D1Ar1 ! for return value
|
|
! If there are less than 16 bytes to copy use the byte copy loop
|
|
BGE $Llong_copy
|
|
|
|
$Lbyte_copy:
|
|
! Simply copy a byte at a time
|
|
SUBS TXRPT, D1Ar3, #1
|
|
BLT $Lend
|
|
$Lloop_byte:
|
|
GETB D1Re0, [A1.2++]
|
|
SETB [A0.2++], D1Re0
|
|
BR $Lloop_byte
|
|
|
|
$Lend:
|
|
! Finally set return value and return
|
|
MOV D0Re0, A0.3
|
|
MOV PC, D1RtP
|
|
|
|
$Llong_copy:
|
|
ANDS D1Ar5, D1Ar1, #7 ! test destination alignment
|
|
BZ $Laligned_dst
|
|
|
|
! The destination address is not 8 byte aligned. We will copy bytes from
|
|
! the source to the destination until the remaining data has an 8 byte
|
|
! destination address alignment (i.e we should never copy more than 7
|
|
! bytes here).
|
|
$Lalign_dst:
|
|
GETB D0Re0, [A1.2++]
|
|
ADD D1Ar5, D1Ar5, #1 ! dest is aligned when D1Ar5 reaches #8
|
|
SUB D1Ar3, D1Ar3, #1 ! decrement count of remaining bytes
|
|
SETB [A0.2++], D0Re0
|
|
CMP D1Ar5, #8
|
|
BNE $Lalign_dst
|
|
|
|
! We have at least (16 - 7) = 9 bytes to copy - calculate the number of 8 byte
|
|
! blocks, then jump to the unaligned copy loop or fall through to the aligned
|
|
! copy loop as appropriate.
|
|
$Laligned_dst:
|
|
MOV D0Ar4, A1.2
|
|
LSR D1Ar5, D1Ar3, #3 ! D1Ar5 = number of 8 byte blocks
|
|
ANDS D0Ar4, D0Ar4, #7 ! test source alignment
|
|
BNZ $Lunaligned_copy ! if unaligned, use unaligned copy loop
|
|
|
|
! Both source and destination are 8 byte aligned - the easy case.
|
|
$Laligned_copy:
|
|
LSRS D1Ar5, D1Ar3, #5 ! D1Ar5 = number of 32 byte blocks
|
|
BZ $Lbyte_copy
|
|
SUB TXRPT, D1Ar5, #1
|
|
|
|
$Laligned_32:
|
|
GETL D0Re0, D1Re0, [A1.2++]
|
|
GETL D0Ar6, D1Ar5, [A1.2++]
|
|
SETL [A0.2++], D0Re0, D1Re0
|
|
SETL [A0.2++], D0Ar6, D1Ar5
|
|
GETL D0Re0, D1Re0, [A1.2++]
|
|
GETL D0Ar6, D1Ar5, [A1.2++]
|
|
SETL [A0.2++], D0Re0, D1Re0
|
|
SETL [A0.2++], D0Ar6, D1Ar5
|
|
BR $Laligned_32
|
|
|
|
! If there are any remaining bytes use the byte copy loop, otherwise we are done
|
|
ANDS D1Ar3, D1Ar3, #0x1f
|
|
BNZ $Lbyte_copy
|
|
B $Lend
|
|
|
|
! The destination is 8 byte aligned but the source is not, and there are 8
|
|
! or more bytes to be copied.
|
|
$Lunaligned_copy:
|
|
! Adjust the source pointer (A1.2) to the 8 byte boundary before its
|
|
! current value
|
|
MOV D0Ar4, A1.2
|
|
MOV D0Ar6, A1.2
|
|
ANDMB D0Ar4, D0Ar4, #0xfff8
|
|
MOV A1.2, D0Ar4
|
|
! Save the number of bytes of mis-alignment in D0Ar4 for use later
|
|
SUBS D0Ar6, D0Ar6, D0Ar4
|
|
MOV D0Ar4, D0Ar6
|
|
! if there is no mis-alignment after all, use the aligned copy loop
|
|
BZ $Laligned_copy
|
|
|
|
! prefetch 8 bytes
|
|
GETL D0Re0, D1Re0, [A1.2]
|
|
|
|
SUB TXRPT, D1Ar5, #1
|
|
|
|
! There are 3 mis-alignment cases to be considered. Less than 4 bytes, exactly
|
|
! 4 bytes, and more than 4 bytes.
|
|
CMP D0Ar6, #4
|
|
BLT $Lunaligned_1_2_3 ! use 1-3 byte mis-alignment loop
|
|
BZ $Lunaligned_4 ! use 4 byte mis-alignment loop
|
|
|
|
! The mis-alignment is more than 4 bytes
|
|
$Lunaligned_5_6_7:
|
|
SUB D0Ar6, D0Ar6, #4
|
|
! Calculate the bit offsets required for the shift operations necesssary
|
|
! to align the data.
|
|
! D0Ar6 = bit offset, D1Ar5 = (32 - bit offset)
|
|
MULW D0Ar6, D0Ar6, #8
|
|
MOV D1Ar5, #32
|
|
SUB D1Ar5, D1Ar5, D0Ar6
|
|
! Move data 4 bytes before we enter the main loop
|
|
MOV D0Re0, D1Re0
|
|
|
|
$Lloop_5_6_7:
|
|
GETL D0Ar2, D1Ar1, [++A1.2]
|
|
! form 64-bit data in D0Re0, D1Re0
|
|
LSR D0Re0, D0Re0, D0Ar6
|
|
MOV D1Re0, D0Ar2
|
|
LSL D1Re0, D1Re0, D1Ar5
|
|
ADD D0Re0, D0Re0, D1Re0
|
|
|
|
LSR D0Ar2, D0Ar2, D0Ar6
|
|
LSL D1Re0, D1Ar1, D1Ar5
|
|
ADD D1Re0, D1Re0, D0Ar2
|
|
|
|
SETL [A0.2++], D0Re0, D1Re0
|
|
MOV D0Re0, D1Ar1
|
|
BR $Lloop_5_6_7
|
|
|
|
B $Lunaligned_end
|
|
|
|
$Lunaligned_1_2_3:
|
|
! Calculate the bit offsets required for the shift operations necesssary
|
|
! to align the data.
|
|
! D0Ar6 = bit offset, D1Ar5 = (32 - bit offset)
|
|
MULW D0Ar6, D0Ar6, #8
|
|
MOV D1Ar5, #32
|
|
SUB D1Ar5, D1Ar5, D0Ar6
|
|
|
|
$Lloop_1_2_3:
|
|
! form 64-bit data in D0Re0,D1Re0
|
|
LSR D0Re0, D0Re0, D0Ar6
|
|
LSL D1Ar1, D1Re0, D1Ar5
|
|
ADD D0Re0, D0Re0, D1Ar1
|
|
MOV D0Ar2, D1Re0
|
|
LSR D0FrT, D0Ar2, D0Ar6
|
|
GETL D0Ar2, D1Ar1, [++A1.2]
|
|
|
|
MOV D1Re0, D0Ar2
|
|
LSL D1Re0, D1Re0, D1Ar5
|
|
ADD D1Re0, D1Re0, D0FrT
|
|
|
|
SETL [A0.2++], D0Re0, D1Re0
|
|
MOV D0Re0, D0Ar2
|
|
MOV D1Re0, D1Ar1
|
|
BR $Lloop_1_2_3
|
|
|
|
B $Lunaligned_end
|
|
|
|
! The 4 byte mis-alignment case - this does not require any shifting, just a
|
|
! shuffling of registers.
|
|
$Lunaligned_4:
|
|
MOV D0Re0, D1Re0
|
|
$Lloop_4:
|
|
GETL D0Ar2, D1Ar1, [++A1.2]
|
|
MOV D1Re0, D0Ar2
|
|
SETL [A0.2++], D0Re0, D1Re0
|
|
MOV D0Re0, D1Ar1
|
|
BR $Lloop_4
|
|
|
|
$Lunaligned_end:
|
|
! If there are no remaining bytes to copy, we are done.
|
|
ANDS D1Ar3, D1Ar3, #7
|
|
BZ $Lend
|
|
! Re-adjust the source pointer (A1.2) back to the actual (unaligned) byte
|
|
! address of the remaining bytes, and fall through to the byte copy loop.
|
|
MOV D0Ar6, A1.2
|
|
ADD D1Ar5, D0Ar4, D0Ar6
|
|
MOV A1.2, D1Ar5
|
|
B $Lbyte_copy
|
|
|
|
.size _memcpy,.-_memcpy
|